Back
Forward
16. Living creatures and conversation
To know how to live is my trade and my art....Michel de Montaigne (1533--1592), Essays
Everything that can be said can be said clearly....Ludwig Wittgenstein (1889--1951), Tractatus
This rummage through special kinds of objects finishes up with the most sophisticated kind: living ones. Note that the finer points of this section, on the arts of conversation, require some knowledge of Chapter V.
Animate objects, such as sea monsters, mad aunts or nasty little dwarves, have a property called life. This behaves somewhat like a before or after routine, but only applies to the following actions:
- Attack
-
The player is making hostile advances...
- Kiss
-
...or excessively friendly ones...
- WakeOther
-
...or simply trying to rouse the creature from sleep.
- ThrowAt
-
The player asked to throw noun at the creature.
- Give
-
The player asked to give noun to the creature...
- Show
-
...or, tantalisingly, just to show it.
- Ask
-
The player asked about something. Just as with a "consult''
topic (see Section 15 passim), the variables consult_from
and consult_words are set up to indicate which words the
object might like to think about. (In addition, second
holds the dictionary value for the first word which isn't
'the', but this is much cruder.)
- Tell
- Likewise, the player is trying to tell the creature about something. The topic is set up just as for Ask (that is, consult_from and consult_words are set, and second also holds the first interesting word).
- Answer
-
This can happen in two ways. One is if the player types "answer <some text>
to troll" or "say <some text> to troll''; the other is if he gives an
order which the parser can't sort out, such as
"troll, og south", and which the orders property hasn't handled
already. Once again, variables are set as if it
were a "consult'' topic. (In addition, noun is set to the
first word, and an attempt to read the text as a number is
stored in the variable special_number: for instance,
"computer, 143" will cause special_number to be set to
143.)
- Order
- This catches any 'orders' which aren't handled by the orders property (see below); action, noun and second are set up as usual.
If the life routine doesn't exist, or returns false, events take their usual course. life routines tend to be quite lengthy, even for relatively static characters such as the priest who stands in the 'Ruins' Shrine:
Object -> priest "mummified priest"
with name "mummified" "priest",
description
"He is desiccated and hangs together only by will-power. Though
his first language is presumably local Mayan, you have the curious
instinct that he will understand your speech.",
initial "Behind the slab, a mummified priest stands waiting, barely
alive at best, impossibly venerable.",
life
[; Answer: "The priest coughs, and almost falls apart.";
Ask: switch(second)
{ 'dictionary', 'book':
if (dictionary has general)
"~The ~bird~ glyph... very funny.~";
"~A dictionary? Really?~";
'glyph', 'glyphs', 'mayan', 'dialect':
"~In our culture, the Priests are ever literate.~";
'king', 'tomb', 'shrine', 'temple', 'altar', 'slab':
"~The King (life! prosperity! happiness!) is buried
deep under this Shrine, where you will never go.~";
}
"~You must find your own answer.~";
Tell: "The priest has no interest in your sordid life.";
Attack, Kiss: remove self;
"The priest desiccates away into dust until nothing
remains, not a breeze nor a bone.";
ThrowAt: move noun to location; <<Attack self>>;
Show, Give:
if (noun==dictionary && dictionary hasnt general)
{ give dictionary general;
"The priest reads a little of the book, laughing
in a hollow, whispering way. Unable to restrain
his mirth, he scratches in a correction somewhere
before returning the book.";
}
"The priest is not very interested in earthly things.";
],
has animate;
(Some of the Ask topics are omitted for brevity.)
Of course an animate object still has before and after routines
like any other, so you can trap many other kinds of behaviour.
Animate creatures can also react_before and react_after, and it's
here that these properties really come into their own:
react_before
[; Drop: if (noun==satellite_gadget)
print "~I wouldn't do that, Mr Bond,~ says Blofeld.^^";
Shoot: remove beretta;
"As you draw, Blofeld snaps his fingers and a giant
magnet snatches the gun from your hand. It hits the
ceiling with a clang. Blofeld silkily strokes his cat.";
];
If Blofeld moves from place to place, these rules move with him.
(link to the answer)
Another example is the coiled snake from 'Balances', which shows that even the tiniest life routine can be adequate for an animal:
Object -> snake "hissing snake"
with name "hissing" "snake",
initial "Tightly coiled at the edge of the chasm is a hissing snake.",
life [; "The snake hisses angrily!"; ],
has animate;
Sometimes creatures should be transparent, sometimes not. Consider these two cases of animate characters, for instance:
-- an urchin with something bulging inside his jacket pocket;
-- a hacker who has a bunch of keys hanging off his belt.
The hacker is transparent, the urchin not. That way the parser prevents the player from referring to whatever the urchin is hiding, even if the player has played the game before, and knows what is in there and what it's called. But the player can look at and be tantalised by the hacker's keys.
When the player types in something like "pilot, fly south'', the result is called an 'order': this is the corresponding idea to an 'action'. (Indeed, if the player types "me, go south'' an ordinary Go s_obj action is produced.)
The order is sent to the pilot's orders property, which may if it wishes obey or react in some other way. Otherwise, the standard game rules will simply print something like "The pilot has better things to do.'' The above priest is especially unhelpful:
orders
[; Go: "~I must not leave the Shrine.~";
NotUnderstood: "~You speak in riddles.~";
default: "~It is not your orders I serve.~";
];
(The NotUnderstood clause is run when the parser couldn't
understand what the player typed: e.g., "priest, go onrth''.)
To clarify the various kinds of conversation:
| Command | rule | action | noun | second | consult |
| "orc, take axe'' | order | Take | axe | 0 | |
| "orc, yes'' | order | Yes | 0 | 0 | |
| "ask orc for the shield'' | order | Give | shield | player | |
| "orc, troll'' | order | NotU... | 'troll' | orc | 3 1 |
| "say troll to orc'' | life | Answer | 'troll' | orc | 2 1 |
| "answer troll to orc'' | life | Answer | 'troll' | orc | 2 1 |
| "orc, tell me about coins'' | life | Ask | orc | 'coins' | 6 1 |
| "ask orc about the big troll'' | life | Ask | orc | 'big' | 4 3 |
| "ask orc about wyvern'' | life | Ask | orc | 0 | 4 1 |
| "tell orc about lost troll'' | life | Tell | orc | 'lost' | 4 2 |
(link to the answer)
Some objects are not alive as such, but can be spoken to: microphones, tape recorders, voice-activated computers and so on. It would be a nuisance to implement these as animate, since they have none of the other characteristics of life: instead, they can be given just the attribute talkable and orders and life properties to deal with the resulting conversation.
(link to the answer)
"Zen, set course for Centauro''This could mostly be implemented by adding verbs like "raise'' to the usual game grammar (see the 'Starcross' computer exercise above), or by carefully trapping the Answer rule. But this is a nuisance, especially if about half the commands you want are recognised as orders in the usual grammar but the other half aren't.
"Zen, speed standard by six''
"Zen, scan 360 orbital''
"Zen, raise the force wall''
"Zen, clear the neutron blasters for firing''
0. -- The parser carries on as usual.
1. -- The grammar routine is saying it has done all the parsing necessary itself, by hand (i.e., using NextWord, TryNumber, NounDomain and the like): the variables action, noun and second must be set up to contain the resulting order.
'verb' -- The parser ignores the usual grammar and instead works through the grammar lines for the given verb (see below).
-'verb' -- Ditto, except that if none of those grammar lines work then the parser goes back and tries the usual grammar as well.
In addition, the grammar routine is free to do some partial parsing of the early words provided it moves on verb_num accordingly to show how much it's got through.
(link to the answer)
(link to the answer)
(link to the answer)
[ Control;
switch(NextWord())
{ 'theta': parsed_number=1; return 1;
'phi': parsed_number=2; return 1;
'range': parsed_number=3; return 1;
default: return -1;
}
];
Verb "comp," * Control "is" number -> SetTo;
And the computer itself needs properties
grammar [; return 'comp,'; ],
orders
[; SetTo:
switch(noun)
{ 1: print "~Theta"; 2: print "~Phi"; 3: print "~Range"; }
print_ret " set to ", second, ".~";
default: "~Does not compute!~";
];
This may not look easier, but it's much more flexible, as the exercises
below will hopefully demonstrate.
Verb "actions." * -> Prepare * -> Simmer * -> Cook;The parser never uses "actions.'' in its ordinary grammar, so this definition has the sole effect of creating three new actions: Prepare, Simmer and Cook.
(link to the answer)
(link to the answer)
(link to the answer)
(link to the answer)
(link to the answer)
(link to the answer)
For more on scope hacking, see Section 28. Note that the variable scope_reason is always set to the constant value TALKING_REASON when the game is trying to work out who you wish to talk to: so it's quite easy to make the scope different for conversational purposes.
(link to the answer)
(link to the answer)
A much fuller example of a 'non-player character' is given in the example game 'The Thief', by Gareth Rees (though it's really an implementation of the gentleman in 'Zork', himself an imitation of the pirate in 'Advent'). The thief is capable of walking around, being followed, stealing things, picking locks, opening doors and so on.
Other good definitions of animate objects to look at are Christopher in 'Toyshop', who will stack up building blocks on request; the kittens in 'Alice Through The Looking-Glass'; the barker in 'Balances', and the cast of 'Advent': the little bird, the snake, bear and dragon, the pirate and of course the threatening little dwarves.
Following people means being able to refer to them after they've left the room: see 'Follow my leader', also by Mr Rees, or the library extension "follower.h'' by Andrew Clover.
See the Inform home page for a way round the Yes awkwardness.
For parsing topics of conversation in advanced ways, see the example game 'Encyclopaedia Frobozzica' by Gareth Rees.
To see how much a good set of characters can do for a game, try playing the prologue of 'Christminster'.